#!/bin/csh -f
#
#	reftree -- create a copy of the postgres reference tree
#

if (! $?PGMASTERTREE ) then
    set MASTER=/usr/local/dev/postgres/mastertree
else
    set MASTER=$PGMASTERTREE
endif

set HOMEDIR = $MASTER/ref

chdir $HOMEDIR
top:
echo ""
echo -n "Full pathname of directory to contain new reference tree ---> "
set TREE = $<
if ( $TREE == "" ) goto top
if ( ! -d $TREE ) then
    echo ""
    echo -n "Directory $TREE does not exist; create (y/n)? "
    set yn = $<
    if ( $yn != y ) then
	echo "aborting reftree creation"
	exit
    endif
    set TREEPATH = `echo $TREE | sed -e 's|/| |g' `
    cd /
    foreach i ($TREEPATH) 
	if (! -d $i) then
	    echo "creating" `pwd`/$i
	    mkdir $i
	endif
	cd $i
    end
endif

if ( -d $HOMEDIR ) then
	echo ===== checking out reference manual =====
	chdir $TREE
	ln -s $HOMEDIR/RCS
	echo "checking out top-level files"
	co RCS/*,v >& /dev/null
	echo done
	foreach i ($HOMEDIR/*)
		if ( -d $i && `basename $i` != RCS) then
			mkdir $TREE/`basename $i`
			chdir $TREE/`basename $i`
			echo "creating $TREE/`basename $i`"
			if (-d $i/RCS) then
				ln -s $i/RCS
				co RCS/*,v >& /dev/null
			endif
			echo done
		endif
	end
	echo ===== done checking out reference manual =====
endif
